advanced_lighting.hlsl

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

// Read matrices row by row, as rin stores them; mul(M, v) is then M * v.
#pragma pack_matrix(row_major)

cbuffer transforms : register(b0)
{
    float4x4 model;
    float4x4 normal_matrix;
    float4x4 view;
    float4x4 projection;
    float3 view_position;
};

struct vs_in
{
    float3 position : POSITION;
    float3 normal : NORMAL;
    float2 uv : TEXCOORD;
};

// Position and normal in world space, where the lighting is done.
struct vs_out
{
    float4 position : SV_Position;
    float3 world : WORLD;
    float3 normal : NORMAL;
    float2 uv : TEXCOORD;
};

vs_out vs_main(vs_in v)
{
    vs_out o;
    float4 world = mul(model, float4(v.position, 1.0));
    o.world = world.xyz;
    o.position = mul(projection, mul(view, world));
    o.normal = mul((float3x3)normal_matrix, v.normal);
    o.uv = v.uv;
    return o;
}

cbuffer light : register(b1)
{
    float3 light_position;
    int blinn;
};

Texture2D albedo : register(t0);
SamplerState linear_wrap : register(s0);

// Deliberately rough (low exponents, wide highlights): the case where the
// difference shows. Blinn needs about four times Phong's exponent to match.
float4 ps_main(vs_out p) : SV_Target
{
    float3 color = albedo.Sample(linear_wrap, p.uv).rgb;
    float3 n = normalize(p.normal);
    float3 to_light = normalize(light_position - p.world);
    float3 to_eye = normalize(view_position - p.world);

    float spec;
    if (blinn)
    {
        float3 halfway = normalize(to_light + to_eye);
        spec = pow(max(dot(n, halfway), 0.0), 4.0);
    }
    else
    {
        spec = pow(max(dot(to_eye, reflect(-to_light, n)), 0.0), 1.0);
    }

    float3 ambient = 0.05 * color;
    float3 diffuse = max(dot(n, to_light), 0.0) * color;
    return float4(ambient + diffuse * 0.5 + 0.5 * spec, 1.0);
}