bloom.rin
src/5.advanced_lighting/7.bloom/bloom.rin · 616 lines
// 7. Bloom
//
// Very bright light seems to spill over its edges, in eyes and cameras alike.
// Faking it takes three steps, all on HDR values:
//
// 1. draw the scene into two targets at once (multiple render targets): the
// colour, and only the parts brighter than 1
// 2. blur the bright parts: a Gaussian, done as a horizontal pass then a
// vertical one, back and forth between two targets (ping-pong), five times
// each way. Two 1D blurs equal one 2D blur, at a fraction of the samples.
// The blur targets are half the window's size: the glow spreads twice as
// far for a quarter of the work
// 3. add the blur back onto the colour, then tone map as in 6
//
// The light cubes are drawn far brighter than 1, so they glow; the lit crates
// mostly stay under the threshold and do not.
//
// Tab bloom on / off
import "../../../includes/win32.rin"
import "../../../includes/math.rin"
import "../../../includes/image.rin"
import "../../../includes/learn/shader.rin"
import "../../../includes/learn/camera.rin"
import "std/print.rin"
// settings
scr_width: i32 = 1280;
scr_height: i32 = 720;
// a unit cube: position, normal, texture coordinate; counter-clockwise from outside
cube_vertices: [288]f32 = {
// right (+x)
0.5, -0.5, 0.5, 1.0, 0.0, 0.0, 0.0, 1.0,
0.5, -0.5, -0.5, 1.0, 0.0, 0.0, 1.0, 1.0,
0.5, 0.5, -0.5, 1.0, 0.0, 0.0, 1.0, 0.0,
0.5, -0.5, 0.5, 1.0, 0.0, 0.0, 0.0, 1.0,
0.5, 0.5, -0.5, 1.0, 0.0, 0.0, 1.0, 0.0,
0.5, 0.5, 0.5, 1.0, 0.0, 0.0, 0.0, 0.0,
// left (-x)
-0.5, -0.5, -0.5, -1.0, 0.0, 0.0, 0.0, 1.0,
-0.5, -0.5, 0.5, -1.0, 0.0, 0.0, 1.0, 1.0,
-0.5, 0.5, 0.5, -1.0, 0.0, 0.0, 1.0, 0.0,
-0.5, -0.5, -0.5, -1.0, 0.0, 0.0, 0.0, 1.0,
-0.5, 0.5, 0.5, -1.0, 0.0, 0.0, 1.0, 0.0,
-0.5, 0.5, -0.5, -1.0, 0.0, 0.0, 0.0, 0.0,
// top (+y)
-0.5, 0.5, 0.5, 0.0, 1.0, 0.0, 0.0, 1.0,
0.5, 0.5, 0.5, 0.0, 1.0, 0.0, 1.0, 1.0,
0.5, 0.5, -0.5, 0.0, 1.0, 0.0, 1.0, 0.0,
-0.5, 0.5, 0.5, 0.0, 1.0, 0.0, 0.0, 1.0,
0.5, 0.5, -0.5, 0.0, 1.0, 0.0, 1.0, 0.0,
-0.5, 0.5, -0.5, 0.0, 1.0, 0.0, 0.0, 0.0,
// bottom (-y)
-0.5, -0.5, -0.5, 0.0, -1.0, 0.0, 0.0, 1.0,
0.5, -0.5, -0.5, 0.0, -1.0, 0.0, 1.0, 1.0,
0.5, -0.5, 0.5, 0.0, -1.0, 0.0, 1.0, 0.0,
-0.5, -0.5, -0.5, 0.0, -1.0, 0.0, 0.0, 1.0,
0.5, -0.5, 0.5, 0.0, -1.0, 0.0, 1.0, 0.0,
-0.5, -0.5, 0.5, 0.0, -1.0, 0.0, 0.0, 0.0,
// front (+z)
-0.5, -0.5, 0.5, 0.0, 0.0, 1.0, 0.0, 1.0,
0.5, -0.5, 0.5, 0.0, 0.0, 1.0, 1.0, 1.0,
0.5, 0.5, 0.5, 0.0, 0.0, 1.0, 1.0, 0.0,
-0.5, -0.5, 0.5, 0.0, 0.0, 1.0, 0.0, 1.0,
0.5, 0.5, 0.5, 0.0, 0.0, 1.0, 1.0, 0.0,
-0.5, 0.5, 0.5, 0.0, 0.0, 1.0, 0.0, 0.0,
// back (-z)
0.5, -0.5, -0.5, 0.0, 0.0, -1.0, 0.0, 1.0,
-0.5, -0.5, -0.5, 0.0, 0.0, -1.0, 1.0, 1.0,
-0.5, 0.5, -0.5, 0.0, 0.0, -1.0, 1.0, 0.0,
0.5, -0.5, -0.5, 0.0, 0.0, -1.0, 0.0, 1.0,
-0.5, 0.5, -0.5, 0.0, 0.0, -1.0, 1.0, 0.0,
0.5, 0.5, -0.5, 0.0, 0.0, -1.0, 0.0, 0.0,
};
vertex_layout: [3]D3D11_INPUT_ELEMENT_DESC = {
{ .SemanticName = "POSITION", .Format = DXGI_FORMAT.DXGI_FORMAT_R32G32B32_FLOAT, .AlignedByteOffset = 0 },
{ .SemanticName = "NORMAL", .Format = DXGI_FORMAT.DXGI_FORMAT_R32G32B32_FLOAT, .AlignedByteOffset = 12 },
{ .SemanticName = "TEXCOORD", .Format = DXGI_FORMAT.DXGI_FORMAT_R32G32_FLOAT, .AlignedByteOffset = 24 },
};
// a floor: position, normal, texture coordinate (repeated 12 times)
plane_vertices: [48]f32 = {
-12.5, -1.0, 12.5, 0.0, 1.0, 0.0, 0.0, 12.0,
12.5, -1.0, 12.5, 0.0, 1.0, 0.0, 12.0, 12.0,
12.5, -1.0, -12.5, 0.0, 1.0, 0.0, 12.0, 0.0,
-12.5, -1.0, 12.5, 0.0, 1.0, 0.0, 0.0, 12.0,
12.5, -1.0, -12.5, 0.0, 1.0, 0.0, 12.0, 0.0,
-12.5, -1.0, -12.5, 0.0, 1.0, 0.0, 0.0, 0.0,
};
lights_constants: struct = {
positions: [4]vec4;
colors: [4]vec4;
}
emit_constants: struct = {
color: vec4; // w = 1: draw this colour unlit (a light cube)
}
blur_constants: struct = {
direction: vec2; // one texel, along x or along y
pad: vec2;
}
combine_constants: struct = {
exposure: f32;
bloom: i32;
pad: [2]i32;
}
// Mirrors `cbuffer transforms` in the shaders, register for register.
transforms: struct = {
model: mat4;
normal_matrix: mat4; // inverse transpose of model, for normals
view: mat4;
projection: mat4;
view_position: vec3; // the eye, in world space
pad: f32;
}
// camera
cam: camera = {};
last_cursor: POINT = {};
scroll: f32 = 0.0;
// keys pressed since they were last read, for toggles
keys_pressed: [256]b32 = {};
key_pressed: proc(key: i32) -> b32 = {
if (!keys_pressed[key]) { return 0; }
keys_pressed[key] = 0;
return 1;
}
// timing
delta_time: f32 = 0.0;
last_frame: f32 = 0.0;
perf_frequency: i64 = 0;
perf_start: i64 = 0;
// Seconds since the first call: what glfwGetTime is to LearnOpenGL.
get_time: proc() -> f32 = {
now: LARGE_INTEGER = {};
if (perf_frequency == 0) {
QueryPerformanceFrequency(now&);
perf_frequency = now.QuadPart;
QueryPerformanceCounter(now&);
perf_start = now.QuadPart;
}
QueryPerformanceCounter(now&);
return cast(now.QuadPart - perf_start, f32) / cast(perf_frequency, f32);
}
// win32: every event for the window (keys, mouse, closing) arrives here
// ---------------------------------------------------------------------
window_proc: proc[callconv(CALLBACK)](hwnd: HWND, msg: UINT, wparam: WPARAM, lparam: LPARAM) -> LRESULT = {
if (msg == WM_DESTROY) {
PostQuitMessage(0);
return 0;
}
// Bit 30 of lparam is set when the key was already down: a repeat.
if (msg == WM_KEYDOWN && wparam < 256 && (lparam & 0x40000000) == 0) {
keys_pressed[wparam] = 1;
return 0;
}
if (msg == WM_MOUSEWHEEL) {
// The high word of wparam is the distance turned, 120 per notch.
scroll += cast(cast((wparam shr 16) & 0xffff, i16), f32) / 120.0;
return 0;
}
return DefWindowProcA(hwnd, msg, wparam, lparam);
}
// process all input: ask Windows whether relevant keys are down this frame and react accordingly
// ----------------------------------------------------------------------------------------------
// The top bit of GetAsyncKeyState is set while a key is held, which makes the SHORT negative.
key_down: proc(key: i32) -> b32 = {
return GetAsyncKeyState(key) < 0;
}
process_input: proc(window: HWND) -> void = {
cursor: POINT = {};
GetCursorPos(cursor&);
// GetAsyncKeyState reads the whole keyboard, so ignore it while another
// window has the focus; glfwGetKey only ever sees its own window's keys.
if (GetForegroundWindow() != window) {
last_cursor = cursor;
scroll = 0.0;
return;
}
if (key_down(VK_ESCAPE)) { DestroyWindow(window); }
if (key_down('W')) { camera_process_keyboard(cam&, camera_movement.forward, delta_time); }
if (key_down('S')) { camera_process_keyboard(cam&, camera_movement.backward, delta_time); }
if (key_down('A')) { camera_process_keyboard(cam&, camera_movement.left, delta_time); }
if (key_down('D')) { camera_process_keyboard(cam&, camera_movement.right, delta_time); }
if (key_down(VK_SPACE)) { camera_process_keyboard(cam&, camera_movement.up, delta_time); }
if (key_down(VK_SHIFT)) { camera_process_keyboard(cam&, camera_movement.down, delta_time); }
// Hold the right mouse button to look around.
if (key_down(VK_RBUTTON)) {
// Screen y grows downwards, so moving the mouse up is a negative dy: pitch up.
camera_process_mouse(cam&, cast(cursor.x - last_cursor.x, f32), cast(last_cursor.y - cursor.y, f32));
}
last_cursor = cursor;
camera_process_scroll(cam&, scroll);
scroll = 0.0;
}
// An immutable buffer: filled once at creation, never written by the CPU again.
create_buffer: proc(device: *ID3D11Device, bind: UINT, data: *const void, size: u64) -> *ID3D11Buffer = {
desc: D3D11_BUFFER_DESC = {
.ByteWidth = cast(size, UINT),
.Usage = D3D11_USAGE.D3D11_USAGE_IMMUTABLE,
.BindFlags = bind,
};
init: D3D11_SUBRESOURCE_DATA = { .pSysMem = data };
buffer: *ID3D11Buffer = null;
ID3D11Device_CreateBuffer(device, desc&, init&, buffer&);
return buffer;
}
// A constant buffer the CPU rewrites, usually every frame. Its size must be a
// multiple of 16 bytes, the size of one HLSL register.
create_constant_buffer: proc(device: *ID3D11Device, size: u64) -> *ID3D11Buffer = {
desc: D3D11_BUFFER_DESC = {
.ByteWidth = cast(size, UINT),
.Usage = D3D11_USAGE.D3D11_USAGE_DYNAMIC,
.BindFlags = D3D11_BIND_CONSTANT_BUFFER,
.CPUAccessFlags = D3D11_CPU_ACCESS_WRITE,
};
buffer: *ID3D11Buffer = null;
ID3D11Device_CreateBuffer(device, desc&, null, buffer&);
return buffer;
}
// WRITE_DISCARD hands back fresh memory, so the GPU never waits on the CPU.
update_buffer: proc(context: *ID3D11DeviceContext, buffer: *ID3D11Buffer, data: *const void, size: u64) -> void = {
mapped: D3D11_MAPPED_SUBRESOURCE = {};
ID3D11DeviceContext_Map(context, cast(buffer, *ID3D11Resource), 0, D3D11_MAP.D3D11_MAP_WRITE_DISCARD, 0, mapped&);
memcpy(mapped.pData, data, size);
ID3D11DeviceContext_Unmap(context, cast(buffer, *ID3D11Resource), 0);
}
// The same buffer in the same register for the vertex, geometry and pixel stages.
bind_constants: proc(context: *ID3D11DeviceContext, slot: UINT, buffer: *ID3D11Buffer) -> void = {
buffers: [1]*ID3D11Buffer = { buffer };
ID3D11DeviceContext_VSSetConstantBuffers(context, slot, 1, buffers[0]&);
ID3D11DeviceContext_GSSetConstantBuffers(context, slot, 1, buffers[0]&);
ID3D11DeviceContext_PSSetConstantBuffers(context, slot, 1, buffers[0]&);
}
// utility function for loading a 2D texture from file, with a full mip chain
// --------------------------------------------------------------------------
// `srgb`: the file stores colours, gamma encoded, and sampling should decode
// them to linear. Data such as normals or roughness is linear already.
load_texture: proc(device: *ID3D11Device, context: *ID3D11DeviceContext, path: [*]const char, srgb: b32) -> *ID3D11ShaderResourceView = {
img: image = image_load(path);
if (img.pixels == null) {
printf("Texture failed to load at path: %s\n", path);
exit(1);
}
desc: D3D11_TEXTURE2D_DESC = {
.Width = cast(img.width, UINT),
.Height = cast(img.height, UINT),
.MipLevels = 0, // the whole chain
.ArraySize = 1,
.Format = srgb ? DXGI_FORMAT.DXGI_FORMAT_R8G8B8A8_UNORM_SRGB : DXGI_FORMAT.DXGI_FORMAT_R8G8B8A8_UNORM,
.SampleDesc = { .Count = 1 },
// Generating mips draws into the texture, so it is a render target too.
.BindFlags = D3D11_BIND_SHADER_RESOURCE | D3D11_BIND_RENDER_TARGET,
.MiscFlags = D3D11_RESOURCE_MISC_GENERATE_MIPS,
};
texture: *ID3D11Texture2D = null;
srv: *ID3D11ShaderResourceView = null;
ID3D11Device_CreateTexture2D(device, desc&, null, texture&);
ID3D11Device_CreateShaderResourceView(device, cast(texture, *ID3D11Resource), null, srv&);
ID3D11DeviceContext_UpdateSubresource(context, cast(texture, *ID3D11Resource), 0, null, img.pixels, cast(img.width * 4, UINT), 0);
ID3D11DeviceContext_GenerateMips(context, srv);
return srv;
}
bind_texture: proc(context: *ID3D11DeviceContext, slot: UINT, srv: *ID3D11ShaderResourceView) -> void = {
views: [1]*ID3D11ShaderResourceView = { srv };
ID3D11DeviceContext_PSSetShaderResources(context, slot, 1, views[0]&);
}
// Draws `count` vertices of `buffer` (32-byte vertices) with `model`.
draw_vertices: proc(context: *ID3D11DeviceContext, constants: *ID3D11Buffer, t: *transforms, buffer: *ID3D11Buffer, count: UINT, model: mat4) -> void = {
stride: UINT = 32;
offset: UINT = 0;
ID3D11DeviceContext_IASetVertexBuffers(context, 0, 1, buffer&, stride&, offset&);
t[0].model = model;
t[0].normal_matrix = m4_normal_matrix(model);
update_buffer(context, constants, t, sizeof(transforms));
ID3D11DeviceContext_Draw(context, count, 0);
}
// A colour texture that can be drawn into (render target view) and then read
// (shader resource view): GL's framebuffer with a texture attachment.
render_target: struct = {
texture: *ID3D11Texture2D;
rtv: *ID3D11RenderTargetView;
srv: *ID3D11ShaderResourceView;
}
create_render_target: proc(device: *ID3D11Device, width: i32, height: i32, format: DXGI_FORMAT, samples: UINT) -> render_target = {
t: render_target = {};
desc: D3D11_TEXTURE2D_DESC = {
.Width = cast(width, UINT),
.Height = cast(height, UINT),
.MipLevels = 1,
.ArraySize = 1,
.Format = format,
.SampleDesc = { .Count = samples },
.BindFlags = D3D11_BIND_RENDER_TARGET | D3D11_BIND_SHADER_RESOURCE,
};
ID3D11Device_CreateTexture2D(device, desc&, null, t.texture&);
ID3D11Device_CreateRenderTargetView(device, cast(t.texture, *ID3D11Resource), null, t.rtv&);
ID3D11Device_CreateShaderResourceView(device, cast(t.texture, *ID3D11Resource), null, t.srv&);
return t;
}
// A depth buffer for drawing into a render target of the same size.
create_depth_buffer: proc(device: *ID3D11Device, width: i32, height: i32, samples: UINT) -> *ID3D11DepthStencilView = {
desc: D3D11_TEXTURE2D_DESC = {
.Width = cast(width, UINT),
.Height = cast(height, UINT),
.MipLevels = 1,
.ArraySize = 1,
.Format = DXGI_FORMAT.DXGI_FORMAT_D24_UNORM_S8_UINT,
.SampleDesc = { .Count = samples },
.BindFlags = D3D11_BIND_DEPTH_STENCIL,
};
texture: *ID3D11Texture2D = null;
dsv: *ID3D11DepthStencilView = null;
ID3D11Device_CreateTexture2D(device, desc&, null, texture&);
ID3D11Device_CreateDepthStencilView(device, cast(texture, *ID3D11Resource), null, dsv&);
return dsv;
}
// A texture cannot be read while it is bound as a target, so the slots are
// emptied before drawing into one.
unbind_textures: proc(context: *ID3D11DeviceContext) -> void = {
views: [8]*ID3D11ShaderResourceView = {};
ID3D11DeviceContext_PSSetShaderResources(context, 0, 8, views[0]&);
}
main: proc() -> i32 = {
// win32: register a window class and create the window
// ----------------------------------------------------
SetProcessDPIAware();
instance: HMODULE = GetModuleHandleA(null);
wc: WNDCLASSA = {
.lpfnWndProc = window_proc,
.hInstance = instance,
.hCursor = LoadCursorA(null, IDC_ARROW),
.lpszClassName = "LearnD3D11",
};
RegisterClassA(wc&);
// A fixed size: the swap chain and every render target keep the size they
// were created with, so nothing needs rebuilding on resize.
style: DWORD = WS_OVERLAPPEDWINDOW & ~(WS_THICKFRAME | WS_MAXIMIZEBOX);
rect: RECT = { .right = scr_width, .bottom = scr_height };
AdjustWindowRect(rect&, style, 0);
window: HWND = CreateWindowExA(0, wc.lpszClassName, "LearnD3D11 (Tab: bloom on / off)", style | WS_VISIBLE, CW_USEDEFAULT, CW_USEDEFAULT,
rect.right - rect.left, rect.bottom - rect.top, null, null, instance, null);
if (window == null) {
printf("Failed to create the window\n");
return -1;
}
// d3d11: create the device, its immediate context and a swap chain
// ----------------------------------------------------------------
swap_desc: DXGI_SWAP_CHAIN_DESC = {
.BufferDesc = {
.Width = cast(scr_width, UINT),
.Height = cast(scr_height, UINT),
.Format = DXGI_FORMAT.DXGI_FORMAT_R8G8B8A8_UNORM,
},
.SampleDesc = { .Count = 1 },
.BufferUsage = DXGI_USAGE_RENDER_TARGET_OUTPUT,
.BufferCount = 2,
.OutputWindow = window,
.Windowed = 1,
.SwapEffect = DXGI_SWAP_EFFECT.DXGI_SWAP_EFFECT_FLIP_DISCARD,
};
feature_level: D3D_FEATURE_LEVEL = D3D_FEATURE_LEVEL.D3D_FEATURE_LEVEL_11_0;
swap_chain: *IDXGISwapChain = null;
device: *ID3D11Device = null;
context: *ID3D11DeviceContext = null;
if (D3D11CreateDeviceAndSwapChain(null, D3D_DRIVER_TYPE.D3D_DRIVER_TYPE_HARDWARE, null, 0, feature_level&, 1, D3D11_SDK_VERSION,
swap_desc&, swap_chain&, device&, null, context&) < 0) {
printf("Failed to create the D3D11 device\n");
return -1;
}
backbuffer: *ID3D11Texture2D = null;
IDXGISwapChain_GetBuffer(swap_chain, 0, IID_ID3D11Texture2D&, cast(backbuffer&, **void));
// The back buffer is viewed as sRGB: what the shaders write is linear, and
// the view gamma-encodes it on the way in (5.2).
backbuffer_view: D3D11_RENDER_TARGET_VIEW_DESC = {
.Format = DXGI_FORMAT.DXGI_FORMAT_R8G8B8A8_UNORM_SRGB,
.ViewDimension = D3D11_RTV_DIMENSION.D3D11_RTV_DIMENSION_TEXTURE2D,
};
backbuffer_rtv: *ID3D11RenderTargetView = null;
ID3D11Device_CreateRenderTargetView(device, cast(backbuffer, *ID3D11Resource), backbuffer_view&, backbuffer_rtv&);
// A depth buffer the size of the window: 24 bits of depth, 8 of stencil.
depth_desc: D3D11_TEXTURE2D_DESC = {
.Width = cast(scr_width, UINT),
.Height = cast(scr_height, UINT),
.MipLevels = 1,
.ArraySize = 1,
.Format = DXGI_FORMAT.DXGI_FORMAT_D24_UNORM_S8_UINT,
.SampleDesc = { .Count = 1 },
.BindFlags = D3D11_BIND_DEPTH_STENCIL,
};
depth_texture: *ID3D11Texture2D = null;
depth_dsv: *ID3D11DepthStencilView = null;
ID3D11Device_CreateTexture2D(device, depth_desc&, null, depth_texture&);
ID3D11Device_CreateDepthStencilView(device, cast(depth_texture, *ID3D11Resource), null, depth_dsv&);
// configure global d3d11 state
// ----------------------------
// GL's conventions rather than D3D's: counter-clockwise triangles face the
// viewer, and nothing is culled.
raster_desc: D3D11_RASTERIZER_DESC = {
.FillMode = D3D11_FILL_MODE.D3D11_FILL_SOLID,
.CullMode = D3D11_CULL_MODE.D3D11_CULL_NONE,
.FrontCounterClockwise = 1,
.DepthClipEnable = 1,
};
raster_state: *ID3D11RasterizerState = null;
ID3D11Device_CreateRasterizerState(device, raster_desc&, raster_state&);
ID3D11DeviceContext_RSSetState(context, raster_state);
viewport: D3D11_VIEWPORT = {
.Width = cast(scr_width, f32),
.Height = cast(scr_height, f32),
.MaxDepth = 1.0,
};
// A sampler: how textures are filtered and what happens past their edges.
sampler_desc: D3D11_SAMPLER_DESC = {
.Filter = D3D11_FILTER.D3D11_FILTER_ANISOTROPIC,
.AddressU = D3D11_TEXTURE_ADDRESS_MODE.D3D11_TEXTURE_ADDRESS_WRAP,
.AddressV = D3D11_TEXTURE_ADDRESS_MODE.D3D11_TEXTURE_ADDRESS_WRAP,
.AddressW = D3D11_TEXTURE_ADDRESS_MODE.D3D11_TEXTURE_ADDRESS_WRAP,
.MaxAnisotropy = 8,
.MaxLOD = D3D11_FLOAT32_MAX,
};
sampler: *ID3D11SamplerState = null;
ID3D11Device_CreateSamplerState(device, sampler_desc&, sampler&);
ID3D11DeviceContext_PSSetSamplers(context, 0, 1, sampler&);
clamp_desc: D3D11_SAMPLER_DESC = sampler_desc;
clamp_desc.Filter = D3D11_FILTER.D3D11_FILTER_MIN_MAG_MIP_LINEAR;
clamp_desc.AddressU = D3D11_TEXTURE_ADDRESS_MODE.D3D11_TEXTURE_ADDRESS_CLAMP;
clamp_desc.AddressV = D3D11_TEXTURE_ADDRESS_MODE.D3D11_TEXTURE_ADDRESS_CLAMP;
clamp_sampler: *ID3D11SamplerState = null;
ID3D11Device_CreateSamplerState(device, clamp_desc&, clamp_sampler&);
ID3D11DeviceContext_PSSetSamplers(context, 1, 1, clamp_sampler&);
// build and compile shaders
// -------------------------
s: shader = shader_create(device, filesystem_path("src/5.advanced_lighting/7.bloom/bloom.hlsl"), vertex_layout);
blur_shader: shader = shader_create(device, filesystem_path("src/5.advanced_lighting/7.bloom/blur.hlsl"), {});
final_shader: shader = shader_create(device, filesystem_path("src/5.advanced_lighting/7.bloom/bloom_final.hlsl"), {});
// set up vertex data and textures
// -------------------------------
cube_vb: *ID3D11Buffer = create_buffer(device, D3D11_BIND_VERTEX_BUFFER, cube_vertices[0]&, sizeof(cube_vertices));
plane_vb: *ID3D11Buffer = create_buffer(device, D3D11_BIND_VERTEX_BUFFER, plane_vertices[0]&, sizeof(plane_vertices));
transforms_buffer: *ID3D11Buffer = create_constant_buffer(device, sizeof(transforms));
lights_buffer: *ID3D11Buffer = create_constant_buffer(device, sizeof(lights_constants));
emit_buffer: *ID3D11Buffer = create_constant_buffer(device, sizeof(emit_constants));
blur_buffer: *ID3D11Buffer = create_constant_buffer(device, sizeof(blur_constants));
combine_buffer: *ID3D11Buffer = create_constant_buffer(device, sizeof(combine_constants));
wood: *ID3D11ShaderResourceView = load_texture(device, context, filesystem_path("resources/textures/wood.png"), 1);
crate: *ID3D11ShaderResourceView = load_texture(device, context, filesystem_path("resources/textures/container2.png"), 1);
cam = camera_create(v3(0.0, 1.5, 6.0), -90.0, -15.0);
bloom: i32 = 1;
// configure floating point framebuffers: two colour targets for the scene,
// and two half-size ones to ping-pong the blur between
// ------------------------------------------------------------------------
hdr16: DXGI_FORMAT = DXGI_FORMAT.DXGI_FORMAT_R16G16B16A16_FLOAT;
color_target: render_target = create_render_target(device, scr_width, scr_height, hdr16, 1);
bright_target: render_target = create_render_target(device, scr_width, scr_height, hdr16, 1);
scene_depth: *ID3D11DepthStencilView = create_depth_buffer(device, scr_width, scr_height, 1);
half_w: i32 = scr_width / 2;
half_h: i32 = scr_height / 2;
pingpong: [2]render_target = { create_render_target(device, half_w, half_h, hdr16, 1), create_render_target(device, half_w, half_h, hdr16, 1) };
half_viewport: D3D11_VIEWPORT = viewport;
half_viewport.Width = cast(half_w, f32);
half_viewport.Height = cast(half_h, f32);
// lighting info
// -------------
lights: lights_constants = {
.positions = {
v4(0.0, 0.5, 1.5, 0.0),
v4(-4.0, 0.5, -3.0, 0.0),
v4(3.0, 0.5, 1.0, 0.0),
v4(-0.8, 2.4, -1.0, 0.0),
},
.colors = {
v4(5.0, 5.0, 5.0, 0.0),
v4(10.0, 0.0, 0.0, 0.0),
v4(0.0, 0.0, 15.0, 0.0),
v4(0.0, 5.0, 0.0, 0.0),
},
};
update_buffer(context, lights_buffer, lights&, sizeof(lights_constants));
crates: [6]mat4 = {
m4_translate(v3(0.0, 1.5, 0.0)),
m4_translate(v3(2.0, 0.0, 1.0)),
m4_mul(m4_translate(v3(-1.0, -1.0, 2.0)), m4_rotate(radians(60.0), v3(1.0, 0.0, 1.0))),
m4_mul(m4_translate(v3(0.0, 2.7, 4.0)), m4_mul(m4_rotate(radians(23.0), v3(1.0, 0.0, 1.0)), m4_scale(v3(1.25, 1.25, 1.25)))),
m4_mul(m4_translate(v3(-2.0, 1.0, -3.0)), m4_rotate(radians(124.0), v3(1.0, 0.0, 1.0))),
m4_translate(v3(-3.0, 0.0, 0.0)),
};
// render loop
// -----------
running: b32 = 1;
while (running) {
msg: MSG = {};
while (PeekMessageA(msg&, null, 0, 0, PM_REMOVE) != 0) {
if (msg.message == WM_QUIT) { running = 0; }
TranslateMessage(msg&);
DispatchMessageA(msg&);
}
// per-frame time logic
// --------------------
current_frame: f32 = get_time();
delta_time = current_frame - last_frame;
last_frame = current_frame;
// input
// -----
process_input(window);
if (key_pressed(VK_TAB)) { bloom = 1 - bloom; }
// 1. render scene into floating point framebuffer: colour and bright parts at once
// --------------------------------------------------------------------------------
targets: [2]*ID3D11RenderTargetView = { color_target.rtv, bright_target.rtv };
unbind_textures(context);
zero: [4]f32 = { 0.0, 0.0, 0.0, 0.0 };
ID3D11DeviceContext_OMSetRenderTargets(context, 2, targets[0]&, scene_depth);
for (i: u32 = 0; i < 2; i += 1) { ID3D11DeviceContext_ClearRenderTargetView(context, targets[i], zero[0]&); }
ID3D11DeviceContext_ClearDepthStencilView(context, scene_depth, D3D11_CLEAR_DEPTH, 1.0, 0);
ID3D11DeviceContext_RSSetViewports(context, 1, viewport&);
ID3D11DeviceContext_IASetPrimitiveTopology(context, D3D11_PRIMITIVE_TOPOLOGY.D3D11_PRIMITIVE_TOPOLOGY_TRIANGLELIST);
bind_constants(context, 0, transforms_buffer);
t: transforms = {
.view = camera_view(cam&),
.projection = m4_perspective(radians(cam.zoom), cast(scr_width, f32) / cast(scr_height, f32), 0.1, 100.0),
.view_position = cam.position,
};
shader_use(context, s&);
bind_constants(context, 1, lights_buffer);
bind_constants(context, 2, emit_buffer);
e: emit_constants = {};
update_buffer(context, emit_buffer, e&, sizeof(emit_constants));
bind_texture(context, 0, wood);
draw_vertices(context, transforms_buffer, t&, plane_vb, 6, m4_identity());
bind_texture(context, 0, crate);
for (i: u32 = 0; i < 6; i += 1) { draw_vertices(context, transforms_buffer, t&, cube_vb, 36, crates[i]); }
// the lights themselves: no lighting, just their own HDR colour
for (i: u32 = 0; i < 4; i += 1) {
e.color = lights.colors[i];
e.color.w = 1.0;
update_buffer(context, emit_buffer, e&, sizeof(emit_constants));
p: vec4 = lights.positions[i];
draw_vertices(context, transforms_buffer, t&, cube_vb, 36, m4_mul(m4_translate(v3(p.x, p.y, p.z)), m4_scale(v3(0.25, 0.25, 0.25))));
}
// 2. blur bright fragments with two-pass Gaussian blur
// ----------------------------------------------------
shader_use(context, blur_shader&);
bind_constants(context, 1, blur_buffer);
ID3D11DeviceContext_RSSetViewports(context, 1, half_viewport&);
source: *ID3D11ShaderResourceView = bright_target.srv;
for (i: u32 = 0; i < 10; i += 1) {
b: blur_constants = {
.direction = i % 2 == 0 ? v2(1.0 / cast(half_w, f32), 0.0) : v2(0.0, 1.0 / cast(half_h, f32)),
};
update_buffer(context, blur_buffer, b&, sizeof(blur_constants));
unbind_textures(context);
ID3D11DeviceContext_OMSetRenderTargets(context, 1, pingpong[i % 2].rtv&, null);
bind_texture(context, 0, source);
ID3D11DeviceContext_Draw(context, 3, 0);
source = pingpong[i % 2].srv;
}
// 3. now render floating point colour buffer to the screen, adding the blur and tone mapping
// ------------------------------------------------------------------------------------------
unbind_textures(context);
ID3D11DeviceContext_OMSetRenderTargets(context, 1, backbuffer_rtv&, null);
ID3D11DeviceContext_RSSetViewports(context, 1, viewport&);
c: combine_constants = { .exposure = 1.0, .bloom = bloom };
update_buffer(context, combine_buffer, c&, sizeof(combine_constants));
shader_use(context, final_shader&);
bind_constants(context, 1, combine_buffer);
bind_texture(context, 0, color_target.srv);
bind_texture(context, 1, source);
ID3D11DeviceContext_Draw(context, 3, 0);
// dxgi: show the image just drawn, waiting for the next vertical blank
// --------------------------------------------------------------------
IDXGISwapChain_Present(swap_chain, 1, 0);
}
return 0;
}